RFC 3339: Date and Time on the Internet: Timestamps

Defined in RFC 3339 as updated by RFC 9557

Mostly compatible with ISO 8601 Timestamp.

Usage

Encodes a particular moment in time (between years 0AD and 9999AD inclusive) with arbitrary sub-second precision.

The date is encoded in Gregorian calendar using year, month, day, hour, minute, second, and fractional second fields, and supports leap years and leap seconds.

Source

; <https://www.rfc-editor.org/rfc/rfc3339.html>

date-time       = full-date "T" full-time

date-fullyear   = 4DIGIT
date-month      = 2DIGIT  ; 01-12
date-mday       = 2DIGIT  ; 01-28, 01-29, 01-30, 01-31 based on
                          ; month/year
time-hour       = 2DIGIT  ; 00-23
time-minute     = 2DIGIT  ; 00-59
time-second     = 2DIGIT  ; 00-58, 00-59, 00-60 based on leap second
                          ; rules
time-secfrac    = "." 1*DIGIT
time-numoffset  = ("+" / "-") time-hour ":" time-minute
time-offset     = "Z" / time-numoffset

partial-time    = time-hour ":" time-minute ":" time-second
                  [time-secfrac]
full-date       = date-fullyear "-" date-month "-" date-mday
full-time       = partial-time time-offset

Info

Rules
date-time, date-fullyear, date-month, date-mday, time-hour, time-minute, time-second, time-secfrac, time-numoffset, time-offset, partial-time, full-date, full-time
Dependencies
Used Builtins
DIGIT

Alphabet

Cited By

Implementations